func initFormProps()
  fvar(NmMask, NmSet, ExMask, ExSet)

  NmMask = 'not(WS_CAPTION or WS_THICKFRAME or WS_MAXIMIZEBOX or WS_MINIMIZEBOX)'
  NmSet = '0' & 'WS_CAPTION or WS_MINIMIZEBOX' & 'WS_CAPTION or WS_THICKFRAME or WS_MAXIMIZEBOX or WS_MINIMIZEBOX' & 'WS_CAPTION' & 'WS_CAPTION' & 'WS_CAPTION or WS_THICKFRAME' & '0' & 'WS_THICKFRAME' & '0' & 'WS_THICKFRAME'

  ExMask = 'not(WS_EX_DLGMODALFRAME or WS_EX_WINDOWEDGE or WS_EX_TOOLWINDOW)'
  ExSet = '0' & '0' & '0' & 'WS_EX_WINDOWEDGE' & 'WS_EX_TOOLWINDOW' & 'WS_EX_TOOLWINDOW' & 'WS_EX_DLGMODALFRAME' & 'WS_EX_TOOLWINDOW' & 'WS_EX_CLIENTEDGE or WS_EX_DLGMODALFRAME' & 'WS_EX_CLIENTEDGE'

  println(ctrl + '.Style := ' + NmSet[BorderStyle] + ' or ' + '(' + NmMask + ' and ' + ctrl + '.Style);')
  println(ctrl + '.ExStyle := ' + ExSet[BorderStyle] + ' or ' + '(' + ExMask + ' and ' + ctrl + '.ExStyle);')
end

func doStart()
  gvar(CUR_CLASS, WIN_PARENT)
  CUR_CLASS = 'TMainClass' 

  gvar(BLK_BODY, BLK_INIT, BLK_FREE, BLK_PUB, BLK_LOC, BLK_MTD_HEAD, BLK_MTD_BODY, BLK_INC, BLK_HEAD)
  BLK_BODY = block.reggen()
  BLK_HEAD = block.reggen()
  BLK_INIT = block.reggen()
  BLK_FREE = block.reggen()
  BLK_PUB = block.reggen()
  BLK_LOC = block.reggen()
  BLK_MTD_HEAD = block.reggen()
  BLK_MTD_BODY = block.reggen()
  BLK_INC = block.reggen()

  gvar(PARENT_CTRL) // текущий родительский элемент
  PARENT_CTRL = ctrl
  WIN_PARENT = ctrl
  include("init_win_ctrl")
  
  block.select(BLK_BODY)
  event(onCreate)
  sys.initall()
  
  block.select(block.reggen())
  println('Program test;')
  println('{$R allres.res}')
  println('uses Windows,kol,Share')
  if(not block.isempty(BLK_INC))
    block.copyhere(BLK_INC)
  end
  println(';')
  println('')
  println('type')
  println(CUR_CLASS + ' = class')
  block.inclvl()
    println('public')
    block.inclvl()
      block.copyhere(BLK_PUB)
      println('')
      println('constructor Create;')
      println('destructor Destroy; override;')
      println('')
      block.copyhere(BLK_MTD_HEAD)
    block.declvl()
  block.declvl()
  println('end;')
  println('')
  println('var mClass:' + CUR_CLASS + ';')
  println('')
  println('constructor ' + CUR_CLASS + '.Create;')
  if(not block.isempty(BLK_LOC))
    println('var')
    block.copyhere(BLK_LOC)
  end
  lng.begin()
    println('inherited;')
    println(ctrl + ' := NewForm(Applet, ', Caption, ');')
    include("property_win_ctrl")
    initFormProps()
    block.copyhere(BLK_INIT)
    block.copyhere(BLK_HEAD)
    println('')
    block.copyhere(BLK_BODY)
  lng.end()
  println('')
  println('destructor ' + CUR_CLASS + '.Destroy;')
  lng.begin()
    block.copyhere(BLK_FREE)
    println(ctrl + '.Free;')
    println('inherited;')
  lng.end()
  println('')
  block.copyhere(BLK_MTD_BODY)
  println('')
  println('begin')
//  println('  Applet := NewApplet(\'HiAsm app\');')
  println('  mClass := ' + CUR_CLASS + '.Create;')
  println('  Run(mClass.' + ctrl + ');')
  println('  mClass.Destroy;')
  println('end.')
  
  block.delete(BLK_BODY)
  block.delete(BLK_INIT)   
  block.delete(BLK_FREE)
  block.delete(BLK_PUB)
  block.delete(BLK_LOC)
  block.delete(BLK_MTD_HEAD)
  block.delete(BLK_MTD_BODY)
  block.delete(BLK_INC)
  block.delete(BLK_HEAD) 
end

func doCaption(Data)
  println(ctrl + '.Caption := ', e_str(Data), ';')
end

include("methods_win_ctrl")