func init
	// defines level
	this.level = isdef("AccessModifier") ? '' : lower(this.props("AccessModifier").value)

	// defines type
	if(isdef("Type"))
		this.type = 'void'
	else
		this.type = code(this.props("Type").value)
	end
	this.typecode = sys.type_code(this.type)

	// defines type modifier
	t = this.props("TypeModifier").value
	this.tMode = 
	((t _and_ 1) ? 'extern ' : '') +
	((t _and_ 2) ? 'readonly ' : '') +
	((t _and_ 4) ? 'sealed ' : '') +
	((t _and_ 8) ? 'static ' : '') +
	((t _and_ 16) ? 'virtual ' : '') +
	((t _and_ 32) ? 'volatile ' : '')

	// defines params types
	if(not isdef("Types"))
		this.arr = this.props("Types").value
	end

	// defines view
	this.hide = isdef("Hidden") ? '*' : ''

	// defines attributes
	if(not isdef("Attributes"))
		arr2 = this.props("Attributes").value
		attr = code(arr2.join(','))
	end

	// defines comments
	arr2.clear()
	ini = block.reg("init").inc().inc()
	inits.add(ini)
	if(not isdef("Comment"))
		arr2 = this.props("Comment").value
		for(i=0; i<arr2.size(); i++)
			ini.println('/// ', code(arr2.get(i)))
		end
	end

	// defines params
	if(this.numvars)
		pname = code(this.pt_var(0).name)
		ptype = code(this.arr.get(0))
		params = '' + ptype + ' ' + pname
		arguments = 'd("' + pname + '_' + this.id + '")'
		// adds method to ini file
		if(this.level == 'public')
			blk_methods.println(this.hide, pname, '_', this.id, '=', code(arr2.get(0)), '. ARG(', ptype, ')|4|', sys.type_code(ptype))
		end
		for(n = 1; n < this.numvars; n++)
			pname = code(this.pt_var(n).name)
			ptype = code(this.arr.get(n))
			params = '' + params + ', ' + ptype + ' ' + pname
			arguments += ' + \', \' + d("' + pname + '_' + this.id + '")'
			// adds method to ini file
			if(this.level == 'public')
				blk_methods.println(this.hide, pname, '_', this.id, '=', code(arr2.get(0)), '. ARG(', ptype, ')|4|', sys.type_code(ptype))
			end
		end
		// initialize params methods
		for(i = 0; i < this.numvars; i++)
			method(code(this.pt_var(i).name))
				pname = cgt.get_func_name()
				pcodename = code(pname)
				return(sub(pcodename, sys.type_code(this.get_type(pname))))
			end
		end
	end

	// declares method
	sys.blocks_store()
	event("onMethod")
	isdef("Attributes") ? '' : ini.println('[', attr, ']')
	mname = isdef("UseName") ? this.codename : code(this.props("Name").value)
	ini.println(len(this.level) ? this.level + ' ' : '', this.tMode, this.type, ' ', mname, '(', params, ')')
	.println('{').inc()
		if(not blk_lvars.empty())
			ini.copyhere(blk_lvars)
		end
		ini.copyhere(blk)
	.dec().println('}')
	sys.blocks_restore()

	// adds method to ini and hws files
	if(this.level == 'public')
		blk_methods.println(this.hide, 'do', mname, '=', code(arr2.get(0)), '. ARG(', params, ')|1|0')
		if(this.type != 'void')
			blk_methods.println(this.hide, 'on', mname, '=Occurs after invoke the method do', mname, ' and returns the result. ARG(', this.type, ')|2|', this.typecode)
		end
		b = block.reggen()
		hws_blocks.add(b)
		b.println('func do', this.codename, '(data)').inc()
			.println('blk.println(this.codename, \'.', this.codename, '(\', ', arguments, ', \');\')')
		.dec().println('end')
	end

	// clean
	arr2.clear()
end

func doReturn(data)
	blk.println('return ', data, ';')
end

func get_type(pname)
	return(this.arr.get(1 + code(copy(pname, 1)) - 2))
end