func init
	// defines level
	this.level = isdef("AccessModifier") ? '' : lower(this.props("AccessModifier").value)

	// initialize types
	if(not isdef("Types"))
		this.arr = this.props("Types").value
	end

	// defines view
	this.hide = isdef("Hidden") ? '*' : ''

	// defines type modifier
	t = this.props("TypeModifier").value
	this.tMode = 
	((t _and_ 1) ? 'static ' : '') +
	((t _and_ 2) ? 'virtual ' : '') +
	((t _and_ 4) ? 'volatile ' : '')

	// defines attributes
	if(not isdef("Attributes"))
		arr2 = this.props("Attributes").value
		attr = code(arr2.join(','))
	end

	// defines comments
	arr2.clear()
	if(not isdef("Comment"))
		arr2 = this.props("Comment").value
	end

	// initialize params
	if(this.numvars)
		pname = code(this.pt_var(0).name)
		ptype = code(this.arr.get(0))
		params = ptype + ' ' + pname
		arguments = 'd("' + pname + '")'
		// adds method to ini file
		if(this.level == 'public')
			blk_methods.println(this.hide, pname, '=Defines the value to operate. ARG(', ptype, ')|4|', sys.type_code(ptype))
		end
		for(n = 1; n < this.numvars; n++)
			pname = code(this.pt_var(n).name)
			ptype = code(this.arr.get(n))
			params += ', ' + ptype + ' ' + pname
			arguments += ' + \', \' + d("' + pname + '")'
			// adds method to ini file
			if(this.level == 'public')
				blk_methods.println(this.hide, pname, '=Defines the value to operate. ARG(', ptype, ')|4|', sys.type_code(ptype))
			end
		end
		// initialize params methods
		for(i = 0; i < this.numvars; i++)
			method(code(this.pt_var(i).name))
				pname = cgt.get_func_name()
				pcodename = code(pname)
				return(sub(pcodename, sys.type_code(this.get_type(pname))))
			end
		end
	end

	// define constructor body
	sys.blocks_store()

	event("onConstructor")

	// declares constructor
	this.class = code(this.parent.get_parent_sdk().props("ClassName").value)
	if(arr2.size())
		for(i=0; i<arr2.size(); i++)
			blk_constructor.println('/// ', code(arr2.get(i)))
		end
	end
	isdef("Attributes") ? '' : blk_constructor.println('[', attr, ']')
	blk_constructor.println(len(this.level) ? this.level + ' ' : '', this.tMode, this.class, '(', code(params), ')')
	.println('{').inc()
		if(not blk_init.empty())
			blk_constructor.copyhere(blk_init)
		end
		if(not blk_lvars.empty())
			blk_constructor.copyhere(blk_lvars)
		end
		blk_constructor.copyhere(blk)
	.dec().println('}')

	sys.blocks_restore()

		// adds method to ini and hws files
	if(this.level == 'public')
		blk_methods.println(this.hide, 'do', this.codename, '=Creates a new instance of the class. ARG(', code(params), ')|1|0')
		b = block.reggen()
		hws_blocks.add(b)
		hws_constructors.add(this.codename)
		hws_args.add(arguments)
		b.println('func do', this.codename, '(data)').inc()
			.println('blk.println(this.codename, \' = new ', this.class, '(\', ', code(arguments), ', \');\')')
			.println()
			.println('// sets a properties')
			s = blk_hws_props.astext()
			s = regex_replace(s, '\\)', ", '', '', blk\\)")
			b.println(code(s))
			.println('// sets event handlers')
			s = blk_hws_events.astext()
			s = regex_replace(s, '\\)', ", '', '', '', blk\\)")
			b.println(code(s))
		.dec().println('end')
	end

	// clean
	arr2.clear()
end

func get_type(pname)
	return(this.arr.get(1 + code(copy(pname, 1)) - 2))
end